@rem ******************************************************************************************************************************************
@rem                ManageEngine OS Deployment Script to change the Keyboard Layout and Language settings of the User
@rem ******************************************************************************************************************************************

@rem LanguageTag determines the Tag determined for each language
@rem For Example 
@rem United States 	: en-US
@rem Great Britain  : en-GB

set LanguageTag=%1

@rem Default value is set to United States
if not "%1"=="" goto SkipDefaultLanguageTag

set LanguageTag=en-US

:SkipDefaultLanguageTag

@rem LanguageID determines the ID determined for each language
@rem For Example 
@rem United States	: 0409:00000409
@rem Great Britain	: 0809:00000809

set LanguageID=%2

@rem Default value is set to United States
if not "%2"=="" goto SkipDefaultLanguageID

set LanguageID=0409:00000409

:SkipDefaultLanguageID

@rem GeoLocationID determines the Geographical Location ID for a particular language
@rem For Example 
@rem United States	: 244
@rem Great Britain	: 242

set GeoLocationID=%3

@rem Default value is set to United States
if not "%3"=="" goto SkipDefaultGeoLocationID

set GeoLocationID=244

:SkipDefaultGeoLocationID

@rem LanguageTag and LanguageID can be found from the below link
@rem "https://docs.microsoft.com/en-us/windows-hardware/manufacture/desktop/default-input-locales-for-windows-language-packs"

@rem GeoLocationID can be found from the below link
@rem "https://docs.microsoft.com/en-us/windows/desktop/intl/table-of-geographical-locations"


@rem Changes the Culture of the user
@rem Culture setting includes the names for the culture, the writing system, the calendar, and formatting for dates and sort strings

PowerShell.exe Set-Culture -CultureInfo %LanguageTag%

@rem Changes the Windows System Locale of the user
@rem System-locale setting determines which code pages, which include ANSI, DOS, and Macintosh, the computer uses by default.

PowerShell.exe Set-WinSystemLocale -SystemLocale %LanguageTag%

@rem Changes the Home location setting of the user
@rem WinHomeLocation is a user setting that describes the home location of the current user account. A home location is the country or region.

if "%3"=="" goto Skip-SetWinHomeLocation

PowerShell.exe Set-WinHomeLocation -GeoId %GeoLocationID%

:Skip-SetWinHomeLocation
@rem Changes the Windows Language setting of the particular User
@rem WinUserLanguageList settings include input method, spelling setting, text prediction setting, and handwriting input mode. 

PowerShell.exe Set-WinUserLanguageList -LanguageList %LanguageTag% -force

@rem WinUILanguageOverride will let you to have a user-preferred display language to be used for the Windows user interface (UI)
@rem If no override setting is used, the display language is dynamically determined from the language list of the user 

PowerShell.exe Set-WinUILanguageOverride -Language %LanguageTag%

@rem Copy the settings applied to Windows screen all the system accounts and the new user accounts to be created later.

>"%cd%\Language.xml" (
	 
	ECHO(^<gs:GlobalizationServices xmlns:gs="urn:longhornGlobalizationUnattend"^>
	ECHO(
	ECHO(	^<!-- user list --^>
	ECHO(	^<gs:UserList^>
	ECHO(		^<gs:User UserID="Current" CopySettingsToDefaultUserAcct="true" CopySettingsToSystemAcct="true"/^>
	ECHO(	^</gs:UserList^>

	if "%3"=="" goto Skip-SetGeoID
	ECHO(
	ECHO(	^<!-- GeoID --^>
	ECHO(	^<gs:LocationPreferences^>^<gs:GeoID Value="%GeoLocationID%"/^>^</gs:LocationPreferences^>
	
	:Skip-SetGeoID
	ECHO(
	ECHO(	^<!-- UI Language Preferences --^>
	ECHO(	^<gs:MUILanguagePreferences^>
	ECHO(		^<gs:MUILanguage Value="%LanguageTag%"/^>
	ECHO(	^</gs:MUILanguagePreferences^>
	ECHO(
	ECHO(	^<!-- system locale --^>
	ECHO(	^<gs:SystemLocale Name="%LanguageTag%"/^>
	ECHO(
	ECHO(	^<!-- input preferences --^>
	ECHO(	^<gs:InputPreferences^>
	ECHO(		^<gs:InputLanguageID Action="add" ID="%LanguageID%" Default="true"/^>
	ECHO(	^</gs:InputPreferences^>
	ECHO(
	ECHO(	^<!-- user locale --^>
	ECHO(	^<gs:UserLocale^>
	ECHO(		^<gs:Locale Name="%LanguageTag%" SetAsCurrent="true" ResetAllSettings="true"/^>
	ECHO(	^</gs:UserLocale^>
	ECHO(
	ECHO(^</gs:GlobalizationServices^>

)

@rem Command to run the xml for copping the settings.
 
control.exe intl.cpl,, /f:"%cd%\Language.xml"

@rem Delete the created Language.xml file

@del "%cd%\Language.xml"